Excel na Web
Coloque seu e-mail aqui para receber GRATUITAMENTE o meu EBOOK →

→ 10 Funções que podem fazer de você um perito em EXCEL

76 O que é e como usar a Função SE no Excel

Aprenda como utilizar a Função SE para criar condições e automatizar suas planilhas.

 A Função SE serve para testar uma condição e retornar um resultado quando a condição for atendida e outro resultado se a condição não for atendida.

Por exemplo, o aluno estará APROVADO se atingir uma média maior que 70, caso contrário estará REPROVADO: =SE(A1>70;"aprovado";"reprovado").

A Função SE pode ser combinada com as Funções lógicas E e OU. Esta combinação é muito útil caso queira usar a Função SE com fórmulas aninhadas para testar mais de uma condição.
 


Como fazer a Função SE no Excel

A Função SE possui 1 parâmetro obrigatório (teste_lógico) e 2 parâmetros opcionais (valor_se_verdadeiro e valor_se_falso).

Sintaxe: SE(
teste_lógico;valor_se_verdadeiro;valor_se_falso)

  • teste_lógico: neste argumento você pode especificar um valor de texto, data, número ou qualquer operador de comparação que forme uma expressão lógica que será testada e avaliada como VERDADEIRO ou FALSO. Por exemplo: o teste lógico pode ser uma expressão como: A1="pago", A1=20, A1>21/03/2019 ou A1>15
  • valor_se_verdadeiro: é o valor que será retornado quando o teste lógico for avaliado como VERDADEIRO, ou seja, quando a condição for atendida. Por exemplo, a fórmula a seguir retornará o texto "Aprovado" se um valor na célula A1 for maior que 70: =SE(A1>70;"Aprovado")
  • valor_se_falsoé o valor que será retornado quando o teste lógico for avaliado como FALSO, ou seja, quando a condição não for atendida. Por exemplo, se você incluir "Reprovado", como terceiro parâmetro à fórmula acima, ela retornará o texto "Aprovado" se um valor na célula A1 for maior que 70. Caso contrário, retornará "Reprovado": =SE(A1>70;"Aprovado";"Reprovado")

[imagem]

Como usar a Fórmula SE passo a passo no Excel

Neste exemplo vamos calcular a comissão de acordo com a quantidade de vendas de cada vendedor. Para isso vamos usar a Função Se do Excel para obter o resultado desejado:



O valor da comissão adotará o seguinte critério: Acima de 5 unidades vendidas será paga a comissão de 10% sobre o valor total de vendas na coluna F; e para vendas abaixo de 5 unidades será pago 7% de comissão.

A Função SE da linha 2 deve ser lida da seguinte forma:

=SE (o número de unidades na célula D2 é > 5; pegue o total na célula F2 x 10%; caso contrário pegue o total na célula F2 x 7%).

Diante do exposto a fórmula real que você deve digitar na célula G2 é:

=SE(D2>5;F2 *10%; F2 *7%)

Como usar a Função Se para exibir um texto no Excel

A Função SE, além de ser útil para fazer cálculos no Excel, pode retornar um número ou um texto qualquer. Para isso deve-se inserir aspas duplas entre os resultados que se quer mostrar. O exemplo anterior poderia ser representado assim:

=SE(D2>5;"Pagar 10%";"Pagar 7%")

Observe na figura abaixo o resultado obtido na coluna G:



Como usar a Função SE com números: maior que, menor que, igual a


Os operadores de comparação permitem realizar diferentes comparações entre dois valores numéricos. Ou seja, podemos verificar, por exemplo, se o primeiro valor é maior que, menor que ou igual ao segundo valor.

Vamos ver alguns exemplos de como fazer a Função Se com cada um dos operadores de comparação:

1 - Função SE maior que: usamos o operador > na fórmula: =SE(A1>0;"OK";-1). Se o número da célula A1 for maior que zero, a fórmula retornará OK. Caso contrário -1 é retornado. 

1 - Função SE menor que: usamos o operador < na fórmula: =SE(A1<0;"OK";1). Se o número da célula A1 for menor que zero, a fórmula retornará OK. Caso contrário 1 é retornado. 

3 - Função SE maior ou igual a: usamos o operador >= na fórmula: =SE(A1>=70;"APROVADO";"REPROVADO"). Se o número da célula A1 for maior ou igual a 70, a fórmula retornará APROVADO. Caso contrário REPROVADO é retornado.

4 - Função SE menor ou igual a: usamos o operador <= na fórmula: =SE(A1<=69;"REPROVADO";"APROVADO). Se o número da célula A1 menor ou igual 69, a fórmula retornará REPROVADO. Caso contrário APROVADO é retornado. 

5 - Função SE igual a: usamos o operador = na fórmula: =SE(A1=0;"OK";"INVALIDO"). Se o número da célula A1 for igual a zero, a fórmula retornará OK. Caso contrário INVALIDO é retornado.

6 - Função SE diferente de: usamos o operador <> na fórmula: =SE(A1<>0;"OK";"INVALIDO"). Se o número da célula A1 for diferente de zero, a fórmula retornará OK. Caso contrário INVALIDO é retornado.

 
[imagem]

Como usar a Função SE com valores de texto

Geralmente para escrever uma Função Se com texto usamos os operadores de comparação igual a (=) e diferente de ( <> )como iremos demonstrar nos exemplos a seguir.




Como usar a Função SE com datas

Como usar a Função SE para célula em branco ou preenchida

Quando uma célula está em branco dizemos que ela está "vazia".

 

 




Se precisar usar mais do que uma condição, ou seja, usar a Função Se com duas condições ou três condições, você deve usar a Função SE Composta. O que é a Função Se composta?

São Funções SE aninhadas, ou seja, Função SE dentro de SE. 

Para aprender a fazer a Função SE dentro de Se com até cinco condições acesse este link:

Como usar a Função SE Composta no Excel


Use outros operadores com a Função SE


O teste de lógica é sempre uma comparação entre os dois valores. Os operadores de comparação são usados, por exemplo, para ver se o valor do primeiro é maior ou menor do que o segundo, ou igual a ele. Você pode usar outros operadores:

  • = Igual a
  • < Menor que
  • <= Menor ou igual a
  • >= Maior ou igual a
  • <> Diferente de

Enquanto a seção de teste de lógica se limita a responder a uma pergunta de verdadeiro ou falso, os dois últimos argumentos da Função SE são flexíveis de modo a atender as necessidades de cada caso.

Agora pratique. Baixe aqui a planilha utilizada neste exemplo, copie as fórmulas
para o restante da coluna e veja o resultado.

Como funciona a Função SE Excel

A Função SE verifica uma condição lógica afim de executar cálculos diferentes dependendo se a resposta à sua pergunta é verdadeiro ou falso. Uma condição lógica é quando um evento somente acontece se outro evento ocorrer também como em: “Se o despertador tocar, eu vou acordar; senão vou continuar dormindo”.

Conteúdo VIP

Coloque o seu email abaixo para receber gratuitamente as atualizações do blog!


Ricardo Fialkoski é o fundador do blog Excel na Web. Trabalha com Excel há mais de dez anos desenvolvendo Soluções Avançadas em Excel e VBA.

76 comentários :

  1. O Ricardo, verifica se você pode me ajudar, estamos fazendo um bolão da primeira fase da copa do mundo e a regra é a seguinte.
    Se acertar o placar ganha 5 pontos, se acertar quem venceu ganha 3 pontos e caso contrario 0, mas eu não estou conseguindo fazer um SE para dar uma resultado na mesma celula.

    ResponderExcluir
    Respostas
    1. Boa noite Sidney! Visto que a pessoa pode ao mesmo tempo acertar o placar e acertar quem ganhou a partida, sua fórmula deve ser parecida com esta:

      =SE(E(A1="Acertou placar";B1="Acertou quem venceu");8;SE(E(A1="Acertou placar";B1="");5;SE(E(A1="";B1="Acertou quem venceu");3;0)))

      Substitua os trechos "Acertou placar", "Acertou quem venceu" ... pelas células que você quer comparar.

      Obrigado pela visita!

      Excluir
  2. Gostava de tirar uma duvida. Tenho uma folha de calculo em excel onnline, o que se passa é que quero , por exemplo o campo B automatico se o A estiver preenchido aumentando +1 a celula anterior B.. Percebeu minha duvida? Mt obrigado..

    ResponderExcluir
    Respostas
    1. Ola, a sua fórmula fica assim: =SE(A1>0;A1+1;"")
      Um abraço!

      Excluir
  3. Boa noite.
    Como ficaria a formula em uma comparação para pegar o maior valor:
    Se:B1>B2=B1senão B2

    ResponderExcluir
    Respostas
    1. Boa noite, a fórmula fica assim: =SE(B1>B2;B1;B2) Um abraço, obrigado pela visita!

      Excluir
  4. estou tentando fazer uma formula para calcular variações de comissões.
    EX. G17 E O VALOR TOTAL DA VENDA
    G18 e o percentual da meta
    entao se vender 70% da meta no ganha nada
    se vender entre 71 e 80% ganha-se 10%
    se vender entre 81 e 90% ganha-se 20%
    se vender entre 91 e 100% ganha=se 30%
    e acima de 101% ganha=se 40%
    tem como me ajudar?

    ResponderExcluir
    Respostas
    1. Olá Luciano, existem duas possibilidades de solução: usar a Função Se aninhada com a Função E para verificar as condições ou criar uma tabela auxiliar e usar o conceito de Função PROCV aproximado. Abraços!

      Excluir
  5. Ola Ricardo,
    Preciso desenvolver uma formula;
    Temos 3 departamentos de venda, com uma meta mensal a ser cumprida, e, para o departamento que tiver a maior media de venda, recebera um premio extra de 2,5% do valor das vendas, como ficaria a formula, poderia me ajudar?
    Agradeço desde ja.

    ResponderExcluir
    Respostas
    1. Ola, após calcular a média de vendas no Excel de cada departamento pode-se usar a Função MAXIMO do Excel para retornar a maior média de vendas. E partir deste resultado aplicar o percentual de 2,5%. Sua fórmula deve ficar parecida com esta:

      =MÁXIMO(A1:C1)*1,025

      onde: A1, B1 e C1 contém a Média de vendas de cada departamento.

      Abraços!

      Excluir
  6. Ricardo preciso fazer uma formula para calcular a porcentagem da nas seguintes condições onde estiver "E"GANHA 1% de comissão e onde estiver "D" E "G" Ganha 0,5 de comissão;obrigada Poliana

    ResponderExcluir
    Respostas
    1. Oi Poliana pelo que entendi você pode usar a Função SE com OU do Excel para calcular a porcentagem de comissão. Sua formula Se com OU deve ficar parecida com esta:

      =SE(A1="E";1%;SE(OU(A1="D";A1="G");0,5%;0))

      Na segunda parte da formula a Função Se irá retornar verdadeiro sempre que uma das condições da Função OU for atendida. Ou seja se A1 for igual a "D" ou "G".

      Abraços!

      Excluir
  7. Olá boa tarde, estou desenvolvendo uma planilha que quero calcular a quantidade de "Ok" que tem na lista. Por exemplo quero que apareça se tem 5 Ok (aparecer somente o numeral 5). Pode me ajudar por favor? Obrigada.

    ResponderExcluir
    Respostas
    1. Oi Tuanny, você deve usar a Função CONT.SE do Excel para contar quantas vezes aparece na sua lista a palavra "OK". A sua fórmula irá ficar assim:

      =CONT.SE(A1:A10;"OK")

      Onde A1:A10 é a sua lista e você deverá substituir de acordo com sua planilha. Um grande Abraço!

      Para um melhor aprendizado veja como usar a Função CONT.SES no Excel: http://goo.gl/6T2go5

      Excluir
  8. Bom dia, quero criar uma formula da seguinte forma.
    Se estiver escrito pago na coluna I4 eu faço a formula E4-D4 se não fica R$0,00. Como faço? tentei assim =SE(I4=PAGO;E4-D4;J4="") mas não deu certo.

    ResponderExcluir
  9. Olá, Ricardo!

    Como utizo a função SE para mudar uma informação aparecer em vermelho? Por G5 maior que G3 aparecer em vermelho.

    Desde já agradeço a atenção

    Abraço

    ResponderExcluir
    Respostas
    1. Olá Fabiano, você precisa usar formatação condicional na célula que contém o valor q ser verificado. Para isso deve criar uma Nova regra de formatação e usar uma fórmula para determinar quais células devem ser formatadas. Então seguida no campo Formatar valores em que esta fórmula é verdadeira digite: =$G$5>$G$3. Por último no botão Formatar defina a cor vermelha. Abraços!

      Excluir
  10. Ricardo, preciso fazer uma fórmula que me mostrou assim, se a célula for de 1-6 ela me mostra "I", se for de 7-10 "II", se for de 11-15 "III" e se for de 16-20 "IV" .. Como eu faço?

    ResponderExcluir
    Respostas
    1. Olá Marcelo, você consegue obter este resultado se Usar a Função Se com E aninhadas no Excel. Acredito que sua fórmula deverá ficar assim:

      =SE(E(D8>=1;D8<=6);"I";SE(E(D8>=7;D8<=10);"II";SE(E(D8>=11;D8<=15);"III";SE(E(D8>=13;D8<=20);"IV";""))))

      Abraços!

      Excluir
    2. Ricardo, gostaria de lhe agradecer pela formula que fez para ajudar o Marcelo, pq eu procurava algo semelhante para a minha formula...e com base na sua explicação, eu consegui, obrigado :-)

      Excluir
    3. Olá Alessandro! Que bom que o exemplo da Função SE lhe ajudou e que estes conceitos estão transformando seus resultados! \o/

      Espero que nossos conteúdos sempre te tragam informações relevantes e que cada vez mais possamos colaborar na sua jornada!

      Grande abraço e muito sucesso pra você! :D

      Excluir
    4. Olá Ricardo! Estou passando tbm para agradecer, pois consegui resolver meu problema tbm com esta resposta. Obrigado!

      Excluir
    5. Olá Mathopitho! Obrigado pelo comentário!

      Fico feliz por saber que nossos artigos contribuíram na resolução do seu problema. Grande Abraço!

      Excluir
  11. Boa tarde Ricardo

    Não estou conseguindo fazer a seguinte formula:

    Se uma determinada celula aparecer "domingo", o valor fica a soma de determinadas celulas, mas for outro dias da semana, a soma de outras celulas. Porém na função SE não estou conseguindo aplicar.
    Pode me ajudar

    ResponderExcluir
    Respostas
    1. Olá! É possível Somar valores com base em várias condições. No seu caso basta aplicar apenas uma condição. Sua fórmula fica assim:

      =SE(C8="DOMINGO";SOMA(H7:H10);SOMA(J7:J10))

      Onde: H7:H10 são os valores referente ao dia de domingo e J7:J0 são os valores referentes aos outros dias da semana.

      Abraços!

      Excluir
  12. Bom dia Ricardo. Na função SE, como poso delimitar um intervalo relativo a data? Por exemplo: tenho 152 células com datas delimitadas entre os anos de 2012 e 2016 e preciso que selecione somente as do ano de 2014.

    ResponderExcluir
    Respostas
    1. Ola Fernando, nesse caso o mais indicado é você usar o recurso de autofiltro no excel para selecionar apenas os dados referentes ao ano de 2014.

      Excluir
  13. Olá Ricardo, gostaria do seu auxilio. Estamos montando uma planilha de controle de autorizações das internações dos pacientes. Criei as celular "Data da internação" e "Data da Alta", a célula seguinte deverá ser a soma desse período me dando o resultado em número, exemplo: Data da internação 01/08/2016, Data da alta: 10/08/2016 = 09; porém queria que nessa célula fosse possível ainda que se o campo "Data da alta" estiver VAZIO, ou seja o paciente ainda está internado, ele considerasse a data de HOJE, e me desse o total baseado nisso. Tentei fazer utilizando a fórmula do SE com a do HOJE(), mas não deu certo.

    ResponderExcluir
    Respostas
    1. Bom dia Priscila! Você está correta em usar a fórmula SE com HOJE, deve estar faltando algum detalhe. Use a Fórmula abaixo e adapte na sua planilha. Sendo que neste exemplo B2 é a Data da Alta e A2 a data do internamento.

      =SE(B2="";HOJE()-A2;B2-A2)

      Qualquer dúvida é só perguntar! Abraços!

      Excluir
    2. Ricardo, deu certo! Muito obrigada.
      Como sugestão, gostaria de plantar a ideia de um canal (Youtube) com pequenas vídeo aulas. Eu com certeza seria uma seguidora fiel. Parabéns por esse trabalho aqui.

      Excluir
    3. Sensacional Priscila! Anotei aqui a sua sugestão, com certeza é uma grande idéia que ja está em meus projetos futuros. Você ja se cadastrou em nossa lista de e-mails? Caso ainda não, se cadastre para receber as atualizações do blog! Até logo!

      Excluir
  14. Bom dia, consigo criar =se para controlar de exames? Tenho um funcionário que tem q fazer exame daqui 2 meses, só que consigo criar em formato de dias, exite essa possibilidade ao invés de dias aparecer falta apenas "3meses" ou apenas "1mes"? Grato

    ResponderExcluir
    Respostas
    1. Bom dia Rafael, o que precisa nesse caso é usar uma fórmula para transformar dias em meses no Excel. Para converter dias em meses no Excel podemos usar a Função ANO em conjunto com a Função MÊS da seguinte forma:

      =(ANO(A1)-ANO(B1))*12+MÊS(A1)-MÊS(B1) onde aplicando no seu exemplo:

      A1 é a data do exame
      B1 é a data atual (hoje)

      Abraços!

      Excluir
  15. Estou adorando receber os emails com as dicas. Aos poucos estou acessando todos. Obrigada Ricardo! ;)

    ResponderExcluir
  16. Estou com um problema, estou usando a função SE comparando dados de colunas diferentes, fui colocando uma função SE dentro de outra função SE, porém ultrapassou o limite de caracteres, como faço pra comparar dados de colunas diferentes. por exemplo =SE(a1:a10=b1:b10;"igual";"diferente") sendo que eu quero comparar o a1 com b1, a2 com b2 e assim sucessivamente. como faço pra fazer isso? obrigado!

    ResponderExcluir
    Respostas
    1. Olá Marcos, para fazer esta comparação com a Função Se no Excel, você precisa usar a Função Se no seu modo matricial, da seguinte forma:Digite a fórmula exatamente como você escreveu no entanto quando você fechar o parenteses pressione CTRL+SHIFT+ENTER para fazer uma função matricial. A sua fórmula terá esta aparência:

      {=SE(A1:A10=B1:B10;"igual";"diferente")}

      Então arraste a fórmula para baixo e terá o resultado esperado.

      Abraços!

      Excluir
  17. Bom dia Professor
    Estou montando uma tabela de tênis (esporte) onde passam de chave os dois melhores saldos de um grupo de três. Porem, nas maneiras que tentei nao deram certo. poderia me auxiliar.
    tentei assim:
    =se(C1>C2:C3;A1;SE(C2>C1:C3;A2;SE(C3>C2:C1;C3;"1ª DO GRUPO A")))
    Mas deu erro. Talvez tenha que utilizar a função E junto.
    E em outra célula gostaria de colocar o 2º colocado deste mesmo grupo.
    ja olhei inúmeras tabelas e nada.

    Desde já agradeço

    ResponderExcluir
    Respostas
    1. Boa tarde Marcus, pelo que entendi do seu exemplo na coluna A você possui os nomes dos concorrentes e na coluna B a pontuação. Desta forma aconselho usar a Função Índice em conjunto com a Função Maior.
      Para o primeiro colocado digite a seguinte fórmula:

      =ÍNDICE(A1:A3;MAIOR(C1:C3;1))

      e para o segundo colocado:

      =ÍNDICE(A1:A3;MAIOR(C1:C3;2))

      Abraços!

      Excluir
  18. Estou com o seguinte problema:
    Em uma planilha tenho uma lista de competidores de uma disputa:
    Competidor Pontuação
    1 - Competidor A - 2.000
    2 - Competidor B - 4.500
    3 - Competidor C - 2.000
    4 - Competidor D - 5.200

    Em outra planilha, quero colocar esta tabela em ordem decrescente, por pontuação. Para isto, utilizo a função máximo e maior para colocar os pontos em ordem decrescente e já sabemos que o 3º e o 4º valor irá se repetir.
    Utilizo a função PROCV para buscar o nome do competidor e colocá-lo na linha de sua respectiva pontuação.
    O problema, é que na 3ª e 4ª linha, pela pontuação se repetir, está aparecendo o nome apenas do Competidor A. Como faço para que apareça A e C na classificação, mesmo as pontuações serem iguais?

    ResponderExcluir
    Respostas
    1. Olá Romulo, creio que você precisa usar um outro método para buscar o nome do competidor, uma espécie de PROCV que traga todos os resultados. Verifique a seguinte postagem e baixe a planilha de exemplo:

      http://www.excelnaweb.com.br/2014/03/funcao-procv-como-retornar-todos-resultados.html

      Abraços!

      Excluir
  19. Olá Ricardo... Preciso de uma formula para calcular uma média... Por Exemplo: A1 (5,5)+ A2 (5,0). Porém se ela for menos que A1(5,5) não mude... como faço?

    ResponderExcluir
    Respostas
    1. Olá André! Pelo que entendi sua fórmula fica com esta estrutura:

      =SE(MÉDIA(A1;A2)<A1;A1;MÉDIA(A1;A2))

      E podemos traduzir assim: Se a média entre os valores de A1 e A2 for menor que o valor de A1, retorne o valor de A1. Caso contrário retorne a média dos valores de A1 e A2.

      Um grande abraço!

      Excluir
  20. Ricardo Fialkoski, parabéns pelo conteúdo. Explicação de forma clara e rápida.

    Obrigada.

    Simone Lopes.

    ResponderExcluir
    Respostas
    1. Oi Simone! Obrigado pelo comentário!

      Espero que consiga turbinar seus resultados com o uso do Excel! :)

      Abração e muito sucesso pra você!

      Excluir
  21. Olá Ricardo, estou tentando fazer uma fórmula que trabalhe com datas. Quero que a coluna A1 tenha uma data e a coluna A2 mostre em tempo real a quantidade de dias. Por exemplo: A1 é 26/10/2016, e se passam 2 dias, então A2 seria 28/10/2016. E ainda nisso, queria colocar uma coluna A3 mostrando a quantidade de dias, ou seja, nesse exemplo o A3 seria o valor 2. Existe formula pra isso? Agradeço desde ja. Abraço

    ResponderExcluir
    Respostas
    1. Olá Lucas, eu simulei aqui a sua necessidade e acredito que você possa resolver de uma maneira bem simples: A1 é 26/10/2016. Em A2 pode usar a Função Hoje, digite: =HOJE(), para finalizar em A3 digite: =A2-A1.
      Um grande abraço!

      Excluir
  22. Olá Ricardo.
    Estou querendo uma fórmula que faça o seguinte:
    Se o resultado de um cáculo em uma célula for maior que 9, dê o resultado zero, caso contrário seja o próprio numero.
    Grato.
    Neivaldo

    ResponderExcluir
    Respostas
    1. Opa Neivaldo, supondo que a célula que contém o cálculo seja A1 use a seguinte fórmula:

      =SE(A1>9;0;A1)

      Abraços!

      Excluir
  23. Ola, estou aqui batendo cabeça pra calcular o valor fixo e adicional. Ex: Se o peso da carga é menor ou igual a 100kg, o valor da diária é 15,58. Passando de 100 o adicional é 0,15 por kg.Me ajude pfvr!

    ResponderExcluir
    Respostas
    1. Olá, uma solução rápida que pensei aqui é usar a função Se no Excel:

      Como exemplo considere que A1 é a célula que contém o peso da carga.

      =SE(A1<=100;15,58;A1*0,15)

      Ou seja: se o peso da carga for menor ou igual a 100, considere 15,58 a diária, caso seja maior o excel multiplica o peso por 0,15 o kilo.

      Abraços!

      Excluir
  24. Olá preciso de um fórmula que calcule entre intervalo de valores e retorne com o texto : Ganhou xxx pontos
    Exemplo compras acima de R$ 1.000 ganhou 200 pontos .

    Estou perdidinhaaaa …

    Estou tentando a fórmula Se , mas está dando erro.
    ( =SE(G20>=K12<K13;L12;"NÃO GANHOU PONTOS ")

    Compras Acima de
    de R$ 1.000,00 GANHOU 200 Pontos
    de R$ 2.000,00 GANHOU 600 Pontos
    de R$ 3.000,00 GANHOU 1.200 Pontos
    de R$ 4.000,00 GANHOU 2.000 pontos

    Alguém pode me ajudar ?

    ResponderExcluir
    Respostas
    1. Olá! Você precisar usar a função se com mais de 3 condições, mais especificamente com 4 condições. No entanto a Função Se testa sempre a primeira condição. Caso não atenda ao critério a Função Se testa a segunda condição. E assim por diante. Desta forma você deve começar do maior para o menor valor como o exemplo abaixo:

      =SE(A1>4000;"Ganhou 2000 pontos";SE(A1>3000;"Ganhou 1200 pontos";SE(A1>2000;"Gsnhou 600 pontos";SE(A1>1000;"Ganhou 200 pontos";""))))

      Um forte abraço e volte sempre!

      Excluir
  25. Ricardo boa boa noite gostaria de saber como uso a formula se para fazer um exercício, tenho duas colunas numeradas aleatoriamente e e quando uma das colunas for zero a resposta deverá ser falsa?

    ResponderExcluir
    Respostas
    1. Olá, você precisa Usar a função SE com OU para testar os valores das duas colunas. Supondo que seja A1 e B1 use da seguinte forma:

      =SE(OU(A1=0;B1=0);"FALSO";"VERDADEIRO")

      Outra opção é usar somente a Função OU com negação:

      =NÃO(OU(A1=0;B1=0))

      Abraços!

      Excluir
  26. Boa noite Ricardo.

    Estou com 3 colunas de situações de produtos numa planilha e preciso que uma delas seja a "situação final", queria criar uma condição na qual a situação final só seria aprovado se o mesmo texto estivesse escrito nas duas. Exemplo: se A1= aprovado e B1=aprovado C1 seria aprovado.
    Se A1=aprovado e B1=análise C1 seria análise
    Se A1= análise e B1=aprovado C1 seria análise.

    Entendeu? Seria possível? Pode me ajudar? Agradeço desde já!

    ResponderExcluir
    Respostas
    1. Ola, é possivel usar a Função Se junto com E no Excel da seguinte forma:
      =SE(E(A1="APROVADO";B1="APROVADO");"APROVADO";"ANALISE")

      Abraços!

      Excluir
  27. Olá Ricardo bom dia!
    Queria uma ajuda, preciso de uma formula para calcular pontos de uma promoção, exemplo:
    Se a pessoa comprar 500,00 ou mais ganha 10 pontos.
    Então seria algo tipo a cada 500,00 gera 10 pontos como fazer isso no Excel.
    No aguardo.
    Grata.
    Gisele Clarice.

    ResponderExcluir
    Respostas
    1. Olá Clarice, o primeiro passo é dividir o valor da compra por 500 e usar a função INT para pegar apenas o número inteiro da fração e multiplicar por 10. Use a seguinte fórmula:

      =INT(A1/500)*10

      Onde A1 é o valor da compra.

      Um grande abraço!

      Excluir
  28. . Situação:
    i. Para pontuação maior ou igual ao 4º Maior, apresentar o texto: Semifinal
    ii. Para pontuação menor ou igual ao 2º Menor, apresentar o texto: Rebaixado
    iii. Para demais situações, apresentar o texto: Mantido
    Preciso de uma formula pra isso oq posso usar?
    Obrigado!!

    ResponderExcluir
    Respostas
    1. Olá, este caso é bem interessante e podemos resolver usando a Função MAIOR, Função MENOR e a Função Se aninhada no Excel. Supondo que a coluna A contem a pontuação digite a seguinte fórmula:

      =SE(A1>=(MAIOR($A$1:$A$10;4));"SEMIFINAL";SE(A1<=(MENOR($A$1:$A$10;2));"REBAIXADO";"MANTIDO"))

      Copie o link e baixe a planilha de exemplo: https://goo.gl/ZeHJVf

      Abraços!

      Excluir
  29. Olá Ricardo, bom dia!!!

    preciso de sua ajuda. estou tentado fazer essa formula: =SE(E57>0;K57=R51;K57=R57) mas está dando erro
    :(

    ResponderExcluir
    Respostas
    1. Olá, na fórmula abaixo você pode ver Como usar a Função SE no Excel para retonar o valor de uma outra célula:

      =SE(E57>0;R51;R57)

      Abraços!

      Excluir
  30. Olá Ricardo, estou tentando uma fórmula para calcular a jornada de trabalho mas considerando 15 minutos (atraso ou adiantado).

    Então em uma célula calculei a hora extra e na outra coluna tentei a fórmula:
    =SE(K5<=tolerância;"00:00";((I5-H5)-Total da Jornada de trabalho)).
    a fórmula está dando certo, mas quando o número é negativo ai da erro.

    Poderia me ajudar?

    ResponderExcluir
    Respostas
    1. Olá, o sistema de datas padrão do Excel não reconhece datas ou horas negativas e retorna o erro #######. Para trabalhar com horas negativas, você precisa alterar o sistema de datas 1900, que é o padrão do Excel, para o sistema de datas 1904. Para isso siga os passo abaixo:

      Clique na Guia Arquivo → Clique em Opções. Na janela que abrir, selecione o subitem Avançado e localize a opção “Usar sistema de datas 1904“.

      Essa alteração deverá corrigir o seu problema.

      Abraços!

      Excluir
  31. COMO FAÇO PARA O RESULTADO DE UMA SUBTRAÇÃO SE FOR IGUAL OU MENOR QUE 100 DAR COMO RESPOSTA ZERO, SO APARECER O QUE FOR MAIOR QUE 100

    ResponderExcluir
    Respostas
    1. Olá André existe a possibilidade de deixar em branco ou zero:

      Para deixar a célula em branco → =SE(A1-B1<=100;"";A1-B1)
      Para retornar zero → =SE(A1-B1<=100;0;A1-B1)

      Abraços!

      Excluir
  32. Bom dia !
    Como faço esta fórmula ?

    =SE(A1="X";"Y";SE(A1<>"X";" MANTER O VALOR QU ESTÁ NA CÉLULA"))
    oBRIGADO

    ResponderExcluir
    Respostas
    1. Olá Ricardo, para fazer a Função SE manter o valor que está na célula, ou seja, retornar valor da própria célula basta seguir o modelo abaixo:

      =SE(A1=X;"Y";A1)

      Excluir
  33. EXISTE A POSSIBILIDADE DE USAR O SE, NESSA CONDIÇÃO? SE UM RESULTADO, COPIAR PARA OUTRA CELULA;

    ResponderExcluir
    Respostas
    1. Olá, isso somente é possível com a criação de uma Função em VBA.
      Abraços!

      Excluir
  34. Bom dia, Ricardo!
    Estou precisando de sua ajuda. Estou tentando uma semana, procurando e não consigo fazer uma operação.
    Preciso que pegue um valor de determinada célula e veja se é < que um valor, se for retorno o valor da célula, se for > que faça uma soma, e assim por diante.
    Vou exemplificar para ficar mais fácil.
    Exemplo:
    A1= 1900
    SE A1 <=1900, então A1, se A1>=1901<=2500, então A1*2+10, se A1 >=2501<=2700, então A1*4+20, e assim por diante.

    Já tentei várias funções e não estou conseguindo!
    Desde já agradeço!

    ResponderExcluir
    Respostas
    1. Ola! Para realizar essa operação no Excel, você pode usar a função SE aninhada para testar cada uma das condições e executar a operação correspondente. Aqui está a fórmula que você pode usar:

      =SE(A1<=1900; A1; SE(E(A1>=1901; A1<=2500); A12+10; SE(E(A1>=2501; A1<=2700); A14+20; "")))

      Explicando a fórmula:

      A primeira condição verifica se o valor em A1 é menor ou igual a 1900. Se for verdadeiro, a célula A1 será retornada.
      Se a primeira condição for falsa, a fórmula passa para a próxima condição.
      A segunda condição verifica se o valor em A1 está compreendido entre 1901 e 2500. Se for verdadeiro, a fórmula calcula A1*2+10.
      Se a segunda condição for falsa, a fórmula passa para a próxima condição.
      A terceira condição verifica se o valor em A1 está compreendido entre 2501 e 2700. Se for verdadeiro, a fórmula calcula A1*4+20.
      Se nenhuma das condições for atendida, a célula será deixada em branco (você pode alterar as aspas duplas "" para um valor padrão se desejar).
      Lembre-se de ajustar a referência da célula A1 na fórmula de acordo com a célula onde você tem o valor a ser avaliado.

      Espero que isso ajude! Se você tiver mais dúvidas, fique à vontade para perguntar

      Excluir
  35. bom dia!! pode me ajudar? preciso de uma fórmula: se a venda for x ela ganha 1,5% se for maior que x ela ganha 1,5% do x + 2% da diferença do x...espero que consiga compreender...desde já agradeço.

    ResponderExcluir
    Respostas
    1. Bom dia! Para criar essa fórmula no Excel, você pode utilizar a função SE juntamente com cálculos matemáticos. Vou apresentar uma fórmula que atende aos critérios mencionados:

      =SE(A2<=x;A20,015;x0,015+(A2-x)*0,02)

      Nesta fórmula, assumimos que o valor da venda está na célula A2 e o valor de referência "x" é uma constante definida por você. Vou explicar como a fórmula funciona:

      A primeira condição (SE) verifica se o valor da venda (A2) é menor ou igual a "x". Se for verdadeiro, o resultado será o valor da venda multiplicado por 0,015 (1,5%).

      Se a primeira condição for falsa (o valor da venda é maior que "x"), a fórmula passa para a próxima parte.
      A segunda parte do cálculo é dividida em duas partes: "x*0,015" representa 1,5% do valor "x", e "(A2-x)*0,02" representa 2% da diferença entre o valor da venda (A2) e "x".

      O resultado final é a soma dessas duas partes.

      Lembre-se de substituir "x" pelo valor de referência desejado na sua fórmula. Por exemplo, se "x" for 10.000, você substituiria todas as ocorrências de "x" por 10.000 na fórmula.

      Espero que esta fórmula atenda às suas necessidades. Se você tiver mais dúvidas, sinta-se à vontade para perguntar!

      Excluir

Comentário(s):